Work with Microsoft Dataverse Data in FoxPro

Load Microsoft Dataverse data into a FoxPro database. This article includes full code and a walk-through of the process.

The CData ODBC driver for Microsoft Dataverse enables you to access Microsoft Dataverse data using the ODBC standard. You can use the CData ODBC Driver for Microsoft Dataverse to integrate Microsoft Dataverse data into your FoxPro project. The procedure below provides a walk-through of the included code sample, which saves Microsoft Dataverse data into tables in a FoxPro database.

About Microsoft Dataverse Data Integration

CData provides the easiest way to access and integrate live data from Microsoft Dataverse (formerly the Common Data Service). Customers use CData connectivity to:

Access both Dataverse Entities and Dataverse system tables to work with exactly the data they need.
Authenticate securely with Microsoft Dataverse in a variety of ways, including Azure Active Directory, Azure Managed Service Identity credentials, and Azure Service Principal using either a client secret or a certificate.
Use SQL stored procedures to manage Microsoft Dataverse entities - listing, creating, and removing associations between entities.

CData customers use our Dataverse connectivity solutions for a variety of reasons, whether they're looking to replicate their data into a data warehouse (alongside other data sources)or analyze live Dataverse data from their preferred data tools inside the Microsoft ecosystem (Power BI, Excel, etc.) or with external tools (Tableau, Looker, etc.).

Getting Started

Connect to Microsoft Dataverse as an ODBC Data Source

If you have not already, first specify connection properties in an ODBC DSN (data source name). This is the last step of the driver installation. You can use the Microsoft ODBC Data Source Administrator to create and configure ODBC DSNs.

NOTE: Set the 'Map To WVarchar' connection property to FALSE (FoxPro uses the ODBC W API and returns the WCHAR for the value type).

You can connect without setting any connection properties for your user credentials. Below are the minimum connection properties required to connect.

InitiateOAuth: Set this to GETANDREFRESH. You can use InitiateOAuth to avoid repeating the OAuth exchange and manually setting the OAuthAccessToken.
OrganizationUrl: Set this to the organization URL you are connecting to, such as https://myorganization.crm.dynamics.com.
Tenant (optional): Set this if you wish to authenticate to a different tenant than your default. This is required to work with an organization not on your default Tenant.

When you connect the Common Data Service OAuth endpoint opens in your default browser. Log in and grant permissions. The OAuth process completes automatically.

Connect and Transfer

To get started, add the code sample to a new project. You can execute the following command to save all tables without displaying them:

DO C:\Temp\sqldump.prg WITH "CData CDS Source", "TESTDB", .f.

Below is the process that the program follows:

Create a new FoxPro database.
Open a connection to Microsoft Dataverse data with the line below:
```
m.hSQLconnection = SQLCONNECT(m.cODBCDSN)
```

If the connection was successful, you can now retrieve the list of tables using the SQLTABLES function. The code below saves the list of tables in sys_tables.dbf:

WAIT WINDOW "Fetching tables for data source '" + m.cODBCDSN + "'..." NOWAIT NOCLEAR
m.nSQLTABLES = SQLTABLES(m.hSQLconnection)

IF lUseDistinctConnections
  WAIT WINDOW "Closing ODBC Connection for data source '" + m.cODBCDSN + "'..." NOWAIT NOCLEAR
  SQLDISCONNECT(m.hSQLconnection)
  m.hSQLconnection = 0 * SQLCONNECT needs to be called again
ENDIF

IF m.nSQLTABLES > 0
  * create local table containing list of tables in db
  COPY TO (m.cImportData + "sys_tables")
  USE

  * convert each table to DBF
  USE (m.cImportData + "sys_tables")
  ALTER TABLE DBF("sys_tables") ;
  ADD COLUMN records i ;
  ADD COLUMN dbfname m

Scan over each table, saving it to a DBF file. The function ODBCtoDBF stores the table in a DBF file and then opens a grid if the lBrowse parameter is set to true:

FUNCTION ODBCtoDBF (cTableName as String, cTableType as String, lBrowse as Logical, lhSQLConnection as Integer)

  WAIT WINDOW ;
  "Converting " + m.cTableType + ' "' + m.cTableName + '" to DBF...' ;
  NOWAIT NOCLEAR

  ACTIVATE SCREEN

  * strip characters incompatible with FoxPro out of the name of the DBF file
  m.cTableAlias		= ""
  m.nTableNameLen		= LEN(m.cTableName)
  m.nTableNameStart	= 1
  
  FOR m.nTableNameStart = 1 TO m.nTableNameLen
    m.cCharacter = SUBSTR(m.cTableName, m.nTableNameStart, 1)	
    IF !ISALPHA(m.cCharacter) .and. (m.nTableNameStart = 1 .or. !ISDIGIT(m.cCharacter))
      m.cTableAlias = m.cTableAlias + "_"
    ELSE
      m.cTableAlias = m.cTableAlias + m.cCharacter
    ENDIF
  ENDFOR

  m.cFromTable = m.cTableName
  m.cTempViewAlias	= m.cTableType + "_" + m.cTableAlias

  LOCAL loException as Exception
  LOCAL lnResultSets
  
  TRY
    * run query
    m.lnResultSets = SQLEXEC(m.lhSQLConnection, ;
      "SELECT * FROM " + m.cFromTable, ;
      m.cTempViewAlias, ;
      aSQLResult)
	  
    IF m.lnResultSets#1
      SET STEP ON
    ENDIF
	
    ACTIVATE SCREEN

  CATCH TO m.loException
    ACTIVATE SCREEN
    ? "Error opening " + m.cTempViewAlias + ":"
    ? m.loException.Message
    ? m.loException.Details
  ENDTRY

  IF !USED(m.cTempViewAlias)
    RETURN
  ENDIF

  * copy records from view cursor to disk
  SELECT * FROM (m.cTempViewAlias) ;
    INTO TABLE (m.cImportData + m.cTableAlias)

  IF USED(m.cTableAlias)

    ACTIVATE SCREEN

    FLUSH	&& flush the buffer to write the data to disk

    IF m.lBrowse
      * pop the table up on screen
      SELECT (m.cTableAlias)
      BROWSE NORMAL NOMODIFY NOWAIT
      ACTIVATE SCREEN
    ELSE
      * close on-disk table for now
      USE IN (m.cTableAlias)
      ACTIVATE SCREEN
    ENDIF
  ENDIF

  IF USED(m.cTempViewAlias)
    USE IN &cTempViewAlias && close SQL view
    ACTIVATE SCREEN
  ENDIF

  WAIT CLEAR

ENDFUNC

You can now save tables of Microsoft Dataverse data as DBF files.

Below is the full code, in FoxPro 9 syntax:

PARAMETERS cODBCDSN, cDatabaseName, lBrowseAfterConvert

*	cODBCDSN				The ODBC data source name, used for the name of the folder where the DBF tables are stored.
*	cDatabaseName			The name of the FoxPro database to use. This database is created if it does not exist. The default is DATABASE_NAME.
*								
*	lBrowseAfterConvert		If ".t." display each table with the BROWSE command after importing it. If ".f." close each table before moving on to the next one.

#define		ODBC_DATASOURCE		"DataSourceName"
#define		DATABASE_NAME		"odbcdata"

m.m_tpath = ".\"                && root directory for data

ON ERROR
SET SAFETY OFF

IF VARTYPE(m.cODBCDSN)#"C" .or. EMPTY(m.cODBCDSN)
  m.cODBCDSN = ODBC_DATASOURCE
ENDIF
IF VARTYPE(m.cDatabaseName)#"C" .or. EMPTY(m.cDatabaseName)
  m.cDatabaseName = DATABASE_NAME
ENDIF

m.cImportData = m.cODBCDSN + "\"

CLOSE TABLES ALL
CLOSE DATABASES ALL

IF !DIRECTORY(m.cImportData)
	MKDIR (m.cImportData)
ENDIF

CREATE DATABASE (m.cDatabaseName)
CREATE CONNECTION (m.cDatabaseName) DATASOURCE (m.cODBCDSN) DATABASE (m.cDatabaseName)

WAIT WINDOW "Opening ODBC Connection for data source '" + m.cODBCDSN + "'..." NOWAIT NOCLEAR
m.hSQLconnection = SQLCONNECT(m.cODBCDSN)

IF m.hSQLconnection > 0
  * Connection successful; get list of tables
  WAIT WINDOW "Fetching tables for data source '" + m.cODBCDSN + "'..." NOWAIT NOCLEAR
  m.nSQLTABLES = SQLTABLES(m.hSQLconnection)

  IF m.nSQLTABLES > 0
    * Create local table containing list of tables in db
    COPY TO (m.cImportData + "sys_tables")
    USE

    * Convert each table to DBF
    USE (m.cImportData + "sys_tables")
    ALTER TABLE DBF("sys_tables") ;
    ADD COLUMN records	i ;
    ADD COLUMN dbfname	m

    SCAN	
    m.cCurrentTable	= TRIM(sys_tables.table_name)
    m.cCurrentTableType	= TRIM(sys_tables.table_type) && Valid values are "SYSTEMTABLE", "TABLE", and "VIEW".
    IF m.cCurrentTableType = "TABLE" or m.cCurrentTableType = "VIEW"

      ODBCtoDBF(m.cCurrentTable, m.cCurrentTableType, m.lBrowseAfterConvert, m.hSQLConnection)
    ELSE
      ACTIVATE SCREEN
      ? "ERROR:", m.cCurrentTable, "Couldn't open ODBC connection."
      =MESSAGEBOX("couldn't open data source " + m.cODBCDSN + " for table " + m.cCurrentTable + ".")
    ENDIF

    ENDSCAN
    BROWSE NORMAL NOWAIT

  ELSE
    =MESSAGEBOX("No tables found in data source " + m.cODBCDSN + ".")
    SET STEP ON
  ENDIF
  
  SQLDISCONNECT(m.hSQLconnection)
  
ELSE
  =MESSAGEBOX("Could not open data source " + m.cODBCDSN + ".")
  SET STEP ON
ENDIF

FUNCTION ODBCtoDBF (cTableName as String, cTableType as String, lBrowse as Logical, lhSQLConnection as Integer)

  WAIT WINDOW ;
  "Converting " + m.cTableType + ' "' + m.cTableName + '" to DBF...' ;
  NOWAIT NOCLEAR

  ACTIVATE SCREEN

  * Strip characters incompatible with FoxPro out of the name of the DBF file
  m.cTableAlias		= ""
  m.nTableNameLen		= LEN(m.cTableName)
  m.nTableNameStart	= 1
  
  FOR m.nTableNameStart = 1 TO m.nTableNameLen
    m.cCharacter = SUBSTR(m.cTableName, m.nTableNameStart, 1)	
    IF !ISALPHA(m.cCharacter) .and. (m.nTableNameStart = 1 .or. !ISDIGIT(m.cCharacter))
      m.cTableAlias = m.cTableAlias + "_"
    ELSE
      m.cTableAlias = m.cTableAlias + m.cCharacter
    ENDIF
  ENDFOR

  m.cFromTable = m.cTableName
  m.cTempViewAlias	= m.cTableType + "_" + m.cTableAlias

  LOCAL loException as Exception
  LOCAL lnResultSets
  
  TRY
    * Run query
    m.lnResultSets = SQLEXEC(m.lhSQLConnection, ;
      "SELECT * FROM " + m.cFromTable, ;
      m.cTempViewAlias, ;
      aSQLResult)
	  
    IF m.lnResultSets#1
      SET STEP ON
    ENDIF
	
    ACTIVATE SCREEN

  CATCH TO m.loException
    ACTIVATE SCREEN
    ? "Error opening " + m.cTempViewAlias + ":"
    ? m.loException.Message
    ? m.loException.Details
  ENDTRY

  IF !USED(m.cTempViewAlias)
    RETURN
  ENDIF

  * Copy records from view cursor to disk
  SELECT * FROM (m.cTempViewAlias) ;
    INTO TABLE (m.cImportData + m.cTableAlias)

  IF USED(m.cTableAlias)

    ACTIVATE SCREEN

    FLUSH	&& Flush the buffer to write the data to disk

    IF m.lBrowse
      * Display the table on screen
      SELECT (m.cTableAlias)
      BROWSE NORMAL NOMODIFY NOWAIT
      ACTIVATE SCREEN
    ELSE
      * Close on-disk table
      USE IN (m.cTableAlias)
      ACTIVATE SCREEN
    ENDIF
  ENDIF

  IF USED(m.cTempViewAlias)
    USE IN &cTempViewAlias && Close SQL view
    ACTIVATE SCREEN
  ENDIF

  WAIT CLEAR

ENDFUNC

Ready to get started?

Download a free trial of the Microsoft Dataverse ODBC Driver to get started:

Download Now

Learn more:

Microsoft Dataverse ODBC Driver

The Microsoft Dataverse ODBC Driver is a powerful tool that allows you to connect with Microsoft Dataverse, directly from any applications that support ODBC connectivity.

Access Microsoft Dataverse like you would a database - access entities through a standard ODBC Driver interface.